FORSKYDNING-funktionen

Returnerer en reference et antal rækker og kolonner fra en startcelle, eventuelt et helt område med en given højde og bredde. Sæt SUM eller MIDDEL uden om for at regne på området.

På engelsk hedder funktionen OFFSET, og i opgaverne kan du skrive begge navne. Alle funktioner på dansk og engelsk

Syntaks

FORSKYDNING(reference; rækker; kolonner; [højde]; [bredde])

reference: Den celle, der startes fra.
rækker: Antal rækker ned. Et negativt tal går op.
kolonner: Antal kolonner til højre. Et negativt tal går til venstre.
højde (valgfri): Hvor mange rækker resultatet dækker. Udelader du den, er det højden af reference.
bredde (valgfri): Hvor mange kolonner resultatet dækker. Udelader du den, er det bredden af reference.

Eksempler

D1=FORSKYDNING(¹A1;²2;³1)

	A	B	D
1	Måned	Salg	95
2	jan	120
3	feb	95
4	mar	140
5	apr	110
6	maj	80
7	jun	130

Med andre ord: Start i A1, og gå 2 rækker ned og 1 kolonne til højre.

D1=SUM(FORSKYDNING(B2;0;0;3;1))

	A	B	D
1	Måned	Salg	355
2	jan	120
3	feb	95
4	mar	140
5	apr	110
6	maj	80
7	jun	130

D1=SUM(FORSKYDNING(B1;TÆL(B2:B7)-2;0;3;1))

	A	B	D
1	Måned	Salg	320
2	jan	120
3	feb	95
4	mar	140
5	apr	110
6	maj	80
7	jun	130

Ofte stillede spørgsmål

Hvordan lægger jeg de sidste tre værdier sammen i en liste, der vokser?

Tæl værdierne, og gå tilbage fra slutningen, fx =SUM(FORSKYDNING(B1;TÆL(B2:B100)-2;0;3;1)). Når du tilføjer en måned, stiger TÆL med én, og området flytter med.

Hvorfor gør FORSKYDNING store projektmapper langsomme?

FORSKYDNING beregnes igen efter hver eneste ændring i projektmappen. INDEKS kan som regel bygge det samme område uden det, fx =SUM(B2:INDEKS(B2:B100;3)).

Hvad hedder FORSKYDNING på engelsk?

OFFSET. Bruger du Excel på engelsk, skriver du OFFSET i stedet for FORSKYDNING. I opgaverne her kan du bruge begge navne.