Excel-hjælp til de små opgaver

Sådan laver du tidsberegning i Excel, også når vagten går over midnat

Tidsberegning i Excel: regn arbejdstid ud, læg timer sammen over 24 timer med [t]:mm og regn nattevagter rigtigt. Med en timeseddel, du kan prøve.

Af Nicolaj, stifter af ExcelOpgaver · · 4 min. læsning

Tidsberegning i Excel handler om to ting: at trække starttid fra sluttid og at give summen det rigtige format. Arbejdstiden for en vagt er =C2-B2, og en uges timer lægger du sammen med SUM. Formatet [t]:mm sørger for, at summen ikke starter forfra efter 24 timer. Siden her viser formlerne på en lille timeseddel, også med en nattevagt, der går over midnat.

Tidsberegning i Excel: sådan gemmer Excel tid

Excel gemmer et klokkeslæt som en brøkdel af et døgn. Et helt døgn er 1, og en time er 1/24. Klokken 12:00 er derfor det halve døgn, altså 0,5, og klokken 6:00 er en fjerdedel, altså 0,25. Derfor kan du trække to tidspunkter fra hinanden som to helt almindelige tal. Hvordan datoer og tid hænger sammen i det samme tal, står i guiden Datoer i Excel.

Du skriver tider med kolon, fx 8:30, så Excel kender dem som klokkeslæt. Skriver du 8,30 med komma, er det bare et tal. Vil du bygge en tid af tal, gør TID (TIME) det. Den tager timer, minutter og sekunder:

C2=TID(A2;B2;0)
ABC
1TimeMinutDøgn
21200,5
3830

TID bygger et klokkeslæt af timer, minutter og sekunder. 12:00 er det halve døgn, så svaret er 0,5.

Otte og en halv time giver et mindre pænt tal, men princippet er det samme:

C3=TID(A3;B3;0)
ABC
1TimeMinutDøgn
2120
38300,354166667

8:30 er 8,5 time delt med 24, og det giver 0,3542. Excel viser tallet som 8:30, når cellen har tidsformat.

I øvegitteret har cellerne ikke tidsformat, så du ser selve brøken. 8:30 står som 0,3542. Det er ikke en fejl, for det er netop det tal, Excel regner med. I dit eget ark vælger du formatet tt:mm, og så står der 8:30 i cellen. Funktionen TIME (HOUR) gør det modsatte af TID. Den henter timetallet ud af en tid. De to navne er lette at forveksle.

Arbejdstid for én dag

Arbejdstiden er sluttidspunktet minus starttidspunktet. Mandag starter vagten klokken 8:00 og slutter klokken 16:30:

D2=C2-B2
ABCD
1DagStartSlutTimer
2Mandag=TIME(8,0,0)=TIME(16,30,0)0,354166667
3Tirsdag=TIME(7,45,0)=TIME(15,15,0)
4Onsdag=TIME(9,0,0)=TIME(17,45,0)
5Torsdag=TIME(22,0,0)=TIME(6,0,0)

Slut minus start giver arbejdstiden. Mandag varer 8 timer og 30 minutter, og det er 0,3542 af et døgn.

Formlen kopierer du ned til de andre dage. Tirsdag og onsdag giver 7:30 og 8:45, og du behøver ikke gøre andet. Så længe vagten slutter samme dag, som den starter, er minus nok.

Nattevagter over midnat

Torsdag er anderledes. Vagten starter klokken 22:00 og slutter klokken 6:00 næste morgen. Sluttidspunktet er et mindre tal end starten, så slut minus start bliver negativt:

D5=C5-B5
ABCD
1DagStartSlutTimer
2Mandag=TIME(8,0,0)=TIME(16,30,0)
3Tirsdag=TIME(7,45,0)=TIME(15,15,0)
4Onsdag=TIME(9,0,0)=TIME(17,45,0)
5Torsdag=TIME(22,0,0)=TIME(6,0,0)-0,666666667

Torsdag slutter vagten klokken 6, og det er et mindre tal end starten klokken 22. Resultatet bliver negativt, og i et rigtigt ark viser cellen #####.

Et negativt klokkeslæt kan Excel ikke vise, så cellen fyldes med kryds. Det er den fejl, du ser på mange timesedler med en nattevagt.

Løsningen er REST (MOD). REST giver resten ved en division, og når du dividerer med 1, regner den i hele døgn. Et negativt tal får et døgn lagt til, mens et positivt tal under 1 forbliver, som det er. Derfor virker =REST(C2-B2;1) både for dagvagter og nattevagter:

D5=REST(C5-B5;1)
ABCD
1DagStartSlutTimer
2Mandag=TIME(8,0,0)=TIME(16,30,0)
3Tirsdag=TIME(7,45,0)=TIME(15,15,0)
4Onsdag=TIME(9,0,0)=TIME(17,45,0)
5Torsdag=TIME(22,0,0)=TIME(6,0,0)0,333333333

REST med 1 lægger et døgn til det negative tal. Så bliver minus 0,6667 til 0,3333, og det er 8 timer.

Sæt formlen ind i hele kolonnen, så behøver du ikke vælge, hvilke dage der er nattevagter. Én begrænsning er der: en vagt på præcis 24 timer giver 0, fordi start og slut er det samme klokkeslæt. Til almindelige vagter betyder det ikke noget.

Prøv selv. Her står nattevagten øverst, så du kan se med det samme, om formlen holder:

Prøv selv

Ugens arbejdstid

Skriv i D2 en formel, der giver arbejdstiden for vagten i række 2. Den skal også virke, når vagten går over midnat, og kunne kopieres ned.

D2
ABCDEF
1Dag Start Slut Timer
2Mandag 0,916666667 0,25
3Tirsdag 0,333333333 0,6875
4Onsdag 0,322916667 0,635416667
5Torsdag 0,375 0,739583333
6
7
8

Klik i D2, og skriv din formel.

Læg timer sammen over 24 timer

Ugens timer lægger du sammen med SUM. Kolonnen Timer er regnet ud med den formel, du lige har lavet, og summen står nederst:

D7=SUM(D2:D5)
ABCD
1DagStartSlutTimer
2Mandag=TIME(8,0,0)=TIME(16,30,0)=MOD(C2-B2,1)
3Tirsdag=TIME(7,45,0)=TIME(15,15,0)=MOD(C3-B3,1)
4Onsdag=TIME(9,0,0)=TIME(17,45,0)=MOD(C4-B4,1)
5Torsdag=TIME(22,0,0)=TIME(6,0,0)=MOD(C5-B5,1)
6
7I alt1,364583333

Ugen varer 32 timer og 45 minutter. Det er 1,3646 døgn, og med formatet [t]:mm viser Excel 32:45.

I øvegitteret ser summen ud som 1,3646, fordi ugen er mere end ét døgn. I et rigtigt ark viser Excel den som 08:45, hvis cellen har det almindelige tidsformat tt:mm. Det format viser kun timerne inden for et døgn, så de 24 timer bliver skjult. Resten er 8 timer og 45 minutter, og det er netop det, der står tilbage.

Skal cellen vise 32:45, har den brug for formatet [t]:mm. Markér cellen, tryk Ctrl+1, vælg Brugerdefineret, og skriv [t]:mm som format. De firkantede klammer betyder, at timerne ikke nulstilles efter 24. Formatet ændrer kun visningen. Tallet i cellen er det samme, så du kan stadig regne videre med det.

Prøv selv. Fire vagter har fået regnet deres timer ud, og du skal bare lægge dem sammen:

Prøv selv

Ugens timer i alt

Skriv i D7 en formel, der lægger ugens fire vagter sammen. Cellerne i kolonnen Timer er allerede regnet ud.

D7
ABCDEF
1Dag Start Slut Timer
2Mandag 0,916666667 0,25 0,333333333
3Tirsdag 0,333333333 0,6875 0,354166667
4Onsdag 0,322916667 0,635416667 0,3125
5Torsdag 0,375 0,739583333 0,364583333
6
7 I alt
8

Klik i D7, og skriv din formel.

Pauser

Har vagten en pause, skriver du den i sin egen kolonne som en tid, fx 0:30 for en halv time. Pausen trækkes fra til sidst:

E2=REST(C2-B2;1)-D2
ABCDE
1DagStartSlutPauseTimer
2Mandag=TIME(8,0,0)=TIME(16,30,0)=TIME(0,30,0)0,333333333

Pausen står i sin egen kolonne og trækkes fra til sidst. 8:30 minus en halv times pause giver 8:00.

REST klarer vagten først, og pausen kommer bagefter. Så virker formlen også, hvis vagten går over midnat. Et lille timeregnskab i Excel er altså bare tre kolonner, der gentages uge efter uge: start, slut og pause.

Fra timer til decimaltal

En timeseddel ender ofte i en løn, og lønnen kræver et decimaltal. Du kan ikke gange 8:30 med en timeløn, fordi tiden er en brøkdel af et døgn. Gang tiden med 24 først:

E2=D2*24
ABCDE
1DagStartSlutTimerDecimaltal
2Mandag=TIME(8,0,0)=TIME(16,30,0)=MOD(C2-B2,1)8,5
3Tirsdag=TIME(7,45,0)=TIME(15,15,0)=MOD(C3-B3,1)

Gang tiden med 24, og du får timerne som decimaltal. 8:30 bliver 8,5.

Så bliver 8:30 til 8,5 timer. Resultatet kan få mange decimaler, så det kan være nødvendigt at afrunde. Det og tabellen over minutter står på siden om minutter til decimaltal i Excel. Hvordan timerne bliver til en lønsedel, kan du læse på siden om lønberegning i Excel.

Prøv det i en opgave

Timer og minutter dukker op, så snart nogen skal lave en timeseddel, en vagtplan eller en regning til en kunde. Formlerne er få, og du har nu set dem alle. Øv formler og datoer med opgaver, der bliver rettet med det samme, under alle emner.

Nicolaj

Om forfatteren

Nicolaj, stifter af ExcelOpgaver

Jeg er softwareudvikler og har bygget ExcelOpgaver fra bunden, også selve regnearket og den motor der regner formlerne ud. For at få det til at virke har jeg skullet forstå hver funktion helt ned i detaljen: hvordan LOPSLAG opfører sig når koden har et mellemrum for meget, hvorfor en dato i virkeligheden er et tal, og hvornår AFRUND giver et andet svar end talformatet.

Mere om Nicolaj

Øv det i opgaver

Opgaver i et rigtigt regneark, der bliver rettet med det samme.

Funktionssider

Ofte stillede spørgsmål

Hvordan lægger jeg timer sammen i Excel?

Brug SUM, og giv cellen formatet [t]:mm. Uden det viser Excel kun timerne efter hele døgn.

Hvorfor starter summen forfra efter 24 timer?

Formatet tt:mm viser kun timerne i døgnet, så 32:45 bliver til 08:45. Skift til [t]:mm, så vises alle timerne.

Hvordan regner jeg en nattevagt ud?

Skriv =REST(C2-B2;1), hvor C2 er sluttidspunktet og B2 starttidspunktet. REST lægger et døgn til, når slut er mindre end start.

Hvordan får jeg timer som decimaltal?

Gang tiden med 24, fx =D2*24. Så bliver 8:30 til 8,5.

Se også