Et tilfældigt helt tal mellem 1 og 6 får du i Excel med =SLUMPMELLEM(1;6). Et tilfældigt navn fra en liste i A2:A6 trækker du med =INDEKS(A2:A6;SLUMPMELLEM(1;5)). Tallene skifter, hver gang arket regner igen, og det kan du låse. Siden her viser alle tre ting og lader dig trække en vinder.
Tilfældige hele tal med SLUMPMELLEM
SLUMPMELLEM (RANDBETWEEN) giver et helt tal mellem to grænser. Begge grænser er med, så =SLUMPMELLEM(1;6) kan give alt fra 1 til 6, som en terning. Du bruger den til lottotal, terninger eller testdata. Sådan gør du:
- Klik i en tom celle.
- Skriv
=SLUMPMELLEM(1;6). - Tryk Enter.
- Tryk F9 for at få et nyt tal.
Vil du have mange tal, så træk i fyldhåndtaget. Hver celle får sit eget tilfældige tal. Du kan også lave tal i et andet interval, fx =SLUMPMELLEM(100;999) til et tilfældigt trecifret tal.
Tilfældigt tal i Excel med decimaler: SLUMP
SLUMP (RAND) tager ingen argumenter og giver et tal mellem 0 og 1, aldrig helt 1. Du skriver =SLUMP() med tomme parenteser. Skal tallet være i et andet interval, ganger du det op: =SLUMP()*100 giver et decimaltal mellem 0 og 100. Skal det ligge mellem 50 og 60, skriver du =50+SLUMP()*10.
Træk et tilfældigt navn fra en liste
Excel kan ikke trække et navn direkte, men du kan trække et nummer og hente det navn, der står på den plads. INDEKS (INDEX) henter nummer x fra en liste:
| A | B | C | |
|---|---|---|---|
| 1 | Deltager | Cem | |
| 2 | Anna | ||
| 3 | Bo | ||
| 4 | Cem | ||
| 5 | Dina | ||
| 6 | Emil |
INDEKS henter nummer 3 fra listen. Det er Cem. SLUMPMELLEM leverer bare tallet, i stedet for at du skriver 3.
Når du bytter 3 ud med SLUMPMELLEM(1;5), får du et tilfældigt nummer fra 1 til 5 og dermed et tilfældigt navn. Den øverste grænse skal passe til antal navne. Hele formlen er =INDEKS(A2:A6;SLUMPMELLEM(1;5)). Prøv selv:
Prøv selv
Træk en vinder
Skriv i D1 en formel, der trækker et tilfældigt navn fra A2:A6. Resultatet skifter, hver gang arket regner igen, så rettelsen ser på, hvordan formlen er bygget.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Deltager | Vinder | ||||
| 2 | Anna | |||||
| 3 | Bo | |||||
| 4 | Cem | |||||
| 5 | Dina | |||||
| 6 | Emil | |||||
| 7 | ||||||
| 8 |
Klik i D1, og skriv din formel.
Rettelsen kan ikke sammenligne med ét bestemt navn, for resultatet er tilfældigt. I stedet tjekker den, at formlen bruger INDEKS og SLUMPMELLEM med de rigtige grænser.
Kan listen vokse, er det smart at lade Excel tælle navnene for dig. =RÆKKER(A2:A6) giver antal navne i området:
| A | B | C | |
|---|---|---|---|
| 1 | Deltager | 5 | |
| 2 | Anna | ||
| 3 | Bo | ||
| 4 | Cem | ||
| 5 | Dina | ||
| 6 | Emil |
RÆKKER tæller, hvor mange rækker et område har. Her er der fem navne.
Skal formlen også tage nye navne med, når du skriver dem under listen, kan du bruge hele kolonnen og tælle de udfyldte celler med TÆLV (COUNTA): =INDEKS(A:A;SLUMPMELLEM(2;TÆLV(A:A))). Overskriften står i række 1 og skal ikke med, så den nederste grænse er 2:
| A | B | C | |
|---|---|---|---|
| 1 | Deltager | 6 | |
| 2 | Anna | ||
| 3 | Bo | ||
| 4 | Cem | ||
| 5 | Dina | ||
| 6 | Emil |
TÆLV tæller de udfyldte celler i kolonnen, overskriften medregnet. Så er der seks, og navnene står i række 2 til 6.
Tilfældige datoer og andre tal
Du kan bruge SLUMPMELLEM til mere end terningkast. Datoer er tal, så =SLUMPMELLEM(46023;46387) giver en tilfældig dato i 2026, når cellen har datoformat. Vil du have en tilfældig procent, kan du dividere: =SLUMPMELLEM(1;100)/100 giver et tal mellem 0,01 og 1. Og skal du bruge testdata til en tabel, fx 20 salgstal mellem 500 og 5.000, skriver du =SLUMPMELLEM(500;5000) og trækker i fyldhåndtaget.
Hvorfor tallene skifter hele tiden
SLUMP og SLUMPMELLEM regner igen, hver gang du ændrer noget i arket, og hver gang du trykker F9. Det er meningen, men det er irriterende, når du har fundet et tal, du vil beholde. Sådan låser du dem:
- Markér cellerne med de tilfældige tal.
- Tryk Ctrl+C.
- Højreklik, og vælg Indsæt speciel og Værdier. I nyere versioner af Excel kan du også trykke Ctrl+Shift+V.
Så bliver formlerne erstattet af de tal, de gav. Tallene står fast, og du kan ikke få dem tilbage som formler. Gem derfor en kopi, hvis du får brug for at trække igen.
Bland en liste i tilfældig rækkefølge
Vil du have hele listen i tilfældig rækkefølge, fx til at fordele opgaver, kan du give hver række et tilfældigt tal. Skriv =SLUMP() i kolonnen ved siden af, og sorter listen efter den kolonne. I Excel 365 kan du klare det med én formel: =SORTER.EFTER(A2:A6;SLUMPMATRIX(RÆKKER(A2:A6))). SORTER.EFTER (SORTBY) sorterer listen efter de tilfældige tal, og SLUMPMATRIX (RANDARRAY) leverer dem. Hvordan sortering ellers fungerer, står på siden om sortering i Excel.
Skal tallene være uden gentagelser, er det også den vej: Lav en liste med tallene fra 1 til 10, og bland den.
Tilfældige tal er ikke til alt
SLUMP og SLUMPMELLEM er gode til eksempler, øvelser og simple lodtrækninger i en klasse eller en forening. De er ikke beregnet til spil om penge eller til noget, hvor tilfældigheden skal kunne bevises. Brug dem til at lave testdata og til at se, hvordan en formel opfører sig.
Prøv det i en opgave
Tilfældige tal er sjove, men du lærer mest af at bygge formlen selv. Øv opslag og funktioner med opgaver, der bliver rettet med det samme. Du skriver formlen, og Excel-motoren i browseren tjekker den med det samme.

Om forfatteren
Nicolaj, stifter af ExcelOpgaver
Jeg er softwareudvikler og har bygget ExcelOpgaver fra bunden, også selve regnearket og den motor der regner formlerne ud. For at få det til at virke har jeg skullet forstå hver funktion helt ned i detaljen: hvordan LOPSLAG opfører sig når koden har et mellemrum for meget, hvorfor en dato i virkeligheden er et tal, og hvornår AFRUND giver et andet svar end talformatet.
Øv det i opgaver
Opgaver i et rigtigt regneark, der bliver rettet med det samme.
Funktionssider
Ofte stillede spørgsmål
Hvordan laver jeg et tilfældigt tal mellem 1 og 100?
Skriv =SLUMPMELLEM(1;100). Begge grænser kan komme ud, så tallet er mindst 1 og højst 100.
Hvordan stopper jeg tallene i at skifte?
Kopiér cellerne, og indsæt dem som værdier med Indsæt speciel og Værdier. Så bliver formlerne til faste tal.
Hvordan trækker jeg et tilfældigt navn?
Skriv =INDEKS(A2:A6;SLUMPMELLEM(1;5)), hvor 5 er antal navne på listen. SLUMPMELLEM vælger en plads, og INDEKS henter navnet.
Kan jeg få tal uden gentagelser?
Ikke direkte med SLUMPMELLEM. Bland i stedet en liste med tallene, fx ved at give hver række et tal med SLUMP og sortere efter det.