Excel-hjælp til de små opgaver

Sammenlign to kolonner i Excel og find dem, der mangler

Sammenlign to lister i Excel og find dem, der mangler, med TÆL.HVIS, XOPSLAG eller betinget formatering. Plus række for række med HVIS. Med en øvelse.

Af Nicolaj, stifter af ExcelOpgaver · · 4 min. læsning

Skal du sammenligne to kolonner i Excel og se, hvem der står på den ene liste, men ikke på den anden, så skriv =HVIS(TÆL.HVIS($C$2:$C$4;A2)>0;"Betalt";"Mangler"). Formlen tjekker, om navnet i A2 findes et sted i den anden liste. Leder du i stedet efter funktionen SAMMENLIGN (MATCH), der finder en værdis placering i en liste, står den forklaret på sin egen side.

Sammenlign to lister i Excel: række for række eller hele listen

Sammenligning kan betyde to forskellige ting, og de to har hver sin formel. Det første spørgsmål er, om to celler på samme række er ens. Det er række for række: Er der bestilt det samme, som der er leveret? Det andet spørgsmål er, om en værdi findes et sted i den anden liste, uanset hvilken række den står på. Det er hele listen: Står tilmeldte Anna blandt dem, der har betalt?

Det er den forskel, der oftest går galt. Lister, der er sorteret forskelligt, kan ikke sammenlignes række for række, for så står Anna på række 3 i den ene liste og på række 7 i den anden. Der skal du bruge en formel, der leder i hele listen.

Find dem, der mangler, med TÆL.HVIS

Du har en liste over tilmeldte i A og en liste over dem, der har betalt, i C. Du vil se, hvem der mangler at betale. TÆL.HVIS (COUNTIF) tæller, hvor mange gange en værdi står i et område. Står Cem ikke i C-listen, er svaret 0:

B2=TÆL.HVIS($C$2:$C$4;A2)
ABC
1TilmeldtAntalBetalt
2Cem0Bo
3AnnaDina
4BoAnna
5Dina
6Emil

TÆL.HVIS tæller, hvor mange gange Cem står i listen over betalte. 0 gange betyder, at Cem ikke har betalt.

Er tallet større end 0, findes navnet. Det bruger du i en HVIS-formel, der skriver Betalt eller Mangler:

B3=HVIS(TÆL.HVIS($C$2:$C$4;A3)>0;"Betalt";"Mangler")
ABC
1TilmeldtStatusBetalt
2CemBo
3AnnaBetaltDina
4BoAnna
5Dina
6Emil

Anna står i listen over betalte, så tallet er over 0, og HVIS svarer Betalt.

C-området er låst med dollartegn: $C$2:$C$4. Det er vigtigt, for formlen skal lede i hele C-listen i hver række. Uden dollartegn flytter området sig ned for hver række, når du kopierer, og så tjekker de nederste rækker kun en del af listen. Prøv selv:

Prøv selv

Hvem mangler at betale?

A2:A6 er alle tilmeldte, og C2:C4 er dem, der har betalt. Skriv i B2 en formel, der giver Betalt, hvis navnet i A2 står i C-listen, og ellers Mangler. Den skal kunne kopieres ned.

B2
ABCDEF
1Tilmeldt Status Betalt
2Cem Bo
3Anna Dina
4Bo Anna
5Dina
6Emil
7
8

Klik i B2, og skriv din formel.

Du kan også bruge =HVIS(ER.TAL(SAMMENLIGN(A2;$C$2:$C$4;0));"Betalt";"Mangler"). SAMMENLIGN finder navnets plads i C-listen, og ER.TAL tjekker, om der kom en plads. Giver SAMMENLIGN en fejl, fordi navnet ikke findes, svarer ER.TAL, at det ikke er et tal, og så står der Mangler. Resultatet er det samme, men TÆL.HVIS er lettere at læse.

Opgaven TÆL.HVIS med en tekstbetingelse træner den del af formlen, der tæller.

Hent en værdi fra den anden liste med XOPSLAG

Vil du have mere end et ja eller nej, kan du hente en værdi fra den anden liste. XOPSLAG (XLOOKUP) leder efter navnet i den ene liste og henter det, der står på samme række i en anden kolonne. Her henter den beløbet, den enkelte har betalt:

B3=XOPSLAG(A3;C2:C4;D2:D4;"Mangler")
ABCD
1TilmeldtBeløbBetaltBeløb
2CemBo450
3Anna600Dina450
4BoAnna600

XOPSLAG leder efter Anna i C-listen og henter beløbet fra D-listen på samme række.

Det fjerde argument er det, der står i cellen, hvis navnet ikke findes. Her er det Mangler, så de, der ikke har betalt, kan ses med det samme:

B2=XOPSLAG(A2;C2:C4;D2:D4;"Mangler")
ABCD
1TilmeldtBeløbBetaltBeløb
2CemManglerBo450
3AnnaDina450
4BoAnna600

Cem står ikke i C-listen, så XOPSLAG giver den tekst, du har valgt som fjerde argument.

Opgaven XOPSLAG med en værdi for ikke fundet går i dybden med det fjerde argument. XOPSLAG findes i Microsoft 365, Excel 2021 og nyere. Har du en ældre version, så brug TÆL.HVIS.

Farv forskellene med betinget formatering

Vil du have farven på de tilmeldte, der mangler, i stedet for en kolonne med tekst, bruger du betinget formatering. Markér A2:A6, vælg Startside, Betinget formatering og Ny regel, og vælg at bruge en formel. Skriv =TÆL.HVIS($C$2:$C$4;A2)=0. Vælg en farve, og klik OK. Alle navne, der ikke står i C-listen, bliver farvet. Der er flere regler at vælge imellem i guiden Betinget formatering.

Dollartegnene er de samme som i HVIS-formlen. C-området er låst, og A2 er det, der skifter, når reglen tjekker hver celle i markeringen.

Række for række med HVIS

Står de to lister i samme rækkefølge, er den enkleste sammenligning et lighedstegn. =A2=B2 giver SAND eller FALSK. Vil du have en tekst, pakker du den ind i HVIS:

C3=HVIS(A3=B3;"Ens";"Forskellig")
ABC
1BestiltLeveretTjek
2SkruerSkruer
3SømBolteForskellig

Række for række sammenligner HVIS to celler på samme linje. Søm er bestilt, men Bolte er leveret.

Opgaven Sammenlign to celler med HVIS viser, hvordan du bygger formlen. Der er et par små detaljer, du skal kende. Lighedstegnet skelner ikke mellem store og små bogstaver:

C2=A2=B2
ABC
1Liste 1Liste 2Ens?
2AnnaannaSAND

Lighedstegnet skelner ikke mellem store og små bogstaver. Anna og anna er ens.

Skal stort og småt tælle som en forskel, bruger du EKSAKT (EXACT):

C2=EKSAKT(A2;B2)
ABC
1Liste 1Liste 2Eksakt?
2AnnaannaFALSK

EKSAKT tager store og små bogstaver med. Her er Anna og anna forskellige.

Typiske fejl

Hvis to ens værdier alligevel ikke bliver set som ens, er der som regel en af disse årsager. Der står et mellemrum efter navnet, som du ikke kan se:

C2=A2=B2
ABC
1Liste 1Liste 2Ens?
2AnnaAnna FALSK

Et mellemrum sidst i B2 er nok til, at de to navne ikke er ens for Excel.

Mellemrum fjerner du først, se siden om at fjerne mellemrum i Excel. En anden årsag er, at tallet i den ene liste er gemt som tekst. Så ser 100 ud som 100, men er ikke ens:

C2=A2=B2
ABC
1Liste 1Liste 2Ens?
2100100FALSK

Tallet 100 i A2 og teksten 100 i B2 ser ens ud, men de er ikke ens. Tekst står til venstre i cellen, tal til højre.

Den tredje fejl er, at området ikke er låst, så de nederste rækker giver forkerte svar. Det mærker du, når de øverste rækker er rigtige, og de nederste er forkerte. Skal du i stedet finde gentagelser i én enkelt liste, står det på siden om at finde og fjerne dubletter i Excel.

Prøv det i en opgave

Sammenligning af lister er noget, du gør, hver gang to kilder skal passe sammen. Det kan være tilmeldte og betalte, lager og bestilling eller to eksporter fra hvert sit system. Prøv opgaven TÆL.HVIS med en tekstbetingelse gratis. Du skriver formlen selv, og den bliver rettet med det samme.

Nicolaj

Om forfatteren

Nicolaj, stifter af ExcelOpgaver

Jeg er softwareudvikler og har bygget ExcelOpgaver fra bunden, også selve regnearket og den motor der regner formlerne ud. For at få det til at virke har jeg skullet forstå hver funktion helt ned i detaljen: hvordan LOPSLAG opfører sig når koden har et mellemrum for meget, hvorfor en dato i virkeligheden er et tal, og hvornår AFRUND giver et andet svar end talformatet.

Mere om Nicolaj

Øv det i opgaver

Opgaver i et rigtigt regneark, der bliver rettet med det samme.

Funktionssider

Ofte stillede spørgsmål

Hvordan sammenligner jeg to kolonner i Excel?

Brug TÆL.HVIS. Formlen =TÆL.HVIS($C$2:$C$4;A2)>0 viser, om værdien i A2 findes i den anden liste.

Hvordan finder jeg forskelle række for række?

Skriv =A2=B2. Du får SAND, hvis cellerne er ens, og FALSK, hvis de er forskellige. Med HVIS kan du skrive en tekst i stedet.

Hvordan farver jeg dem, der mangler?

Brug betinget formatering med formlen =TÆL.HVIS($C$2:$C$4;A2)=0. Så bliver de celler farvet, hvis værdi ikke står i den anden liste.

Hvad gør funktionen SAMMENLIGN?

Den finder placeringen af en værdi i en liste. Den bruges ofte sammen med INDEKS til at slå værdier op.

Se også